UMIhelp
Разработка сайта на UMI.CMS => Шаблоны XSLT => Тема начата: goodprofy от 02 Июня 2014, 11:24:38
-
А вот собственно и я - парень с вебинара обещавший изложить проблему на форуме.
Сайт А
http://mironline.com.ua/market/svetilniki/svetil_niki_dekorativnye/potolochnye_svetilniki/potolochnye_svetilniki/svetil_nik_potolochnyj_massive_30050_56_10/
Теги выводятся внизу страниц, все нормально.
Сайт Б
http://kids.mironline.com.ua/market/igrushki/radioupravlyaemye_modeli/mashinka_mercedes_benz_chernaya_1_14/
Код одинаковый, но выводится 1 тег из 8!
Код вызова в шаблоне
<xsl:apply-templates select="document(concat('udata://stat/tagsCloud/notemplate/1000/',@id))"
mode="objecttags"/>
Код обработки
<xsl:template match="udata[@method='tagsCloud']" mode="objecttags">
<xsl:apply-templates select="//item" mode="objecttags"/>
</xsl:template>
<xsl:template match="item" mode="objecttags">
<xsl:variable name="str">
<xsl:call-template name="string-replace-all">
<xsl:with-param name="text" select="."/>
<xsl:with-param name="replace" select="' '"/>
<xsl:with-param name="by">
<xsl:text>%20</xsl:text>
</xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="document(concat('udata://content/pagesByAccountTags/',$str))" mode="objecttag"/>
</xsl:template>
<xsl:template match="udata[@method='pagesByAccountTags']" mode="objecttag">
<xsl:apply-templates select="//item" mode="objecttag"/>
</xsl:template>
<xsl:template match="item" mode="objecttag">
<div class="tag_item">
<a href="{@link}" id="tag_id_{@id}">
<xsl:value-of select="."/>
</a>
</div>
</xsl:template>
<xsl:template name="string-replace-all">
<xsl:param name="text"/>
<xsl:param name="replace"/>
<xsl:param name="by"/>
<xsl:choose>
<xsl:when test="contains($text, $replace)">
<xsl:value-of select="substring-before($text,$replace)"/>
<xsl:value-of select="$by"/>
<xsl:call-template name="string-replace-all">
<xsl:with-param name="text"
select="substring-after($text,$replace)"/>
<xsl:with-param name="replace" select="$replace"/>
<xsl:with-param name="by" select="$by"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$text"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
Код вызова страницы(для тех кто хочет полностью попробовать)
<xsl:apply-templates
select="document('udata://content/pagesByAccountTags/')"/>
Код страницы
<xsl:template match="udata[@method='pagesByAccountTags']">
<div class="menu_inside">
<div id="navibar"><a href="/">Главная</a>→
<a href="{$request-uri}">Тег -<xsl:value-of select="//tags"/>
</a>
↓
</div>
</div>
<h1>Тег -<xsl:value-of select="//tags"/>
</h1>
<xsl:apply-templates select="//item"/>
</xsl:template>
<xsl:template match="udata[@method='pagesByAccountTags']//item">
<p>
<span><xsl:value-of select="position()"/>.
</span>
<a href="{@link}" id="tag_id_{@id}">
<xsl:value-of select="."/>
</a>
</p>
</xsl:template>
Выводил $str, там все теги есть, но сюда <xsl:apply-templates select="document(concat('udata://content/pagesByAccountTags/',$str))" mode="objecttag"/>
почему-то попадает только 1 тег, куда делись остальные 7, не понятно и совсем не понятно - тег который выводится не находится в позиции first или last.
Теги есть с пробелами и без, за обработку пробелов отвечает <xsl:template name="string-replace-all"/>
Вот почему на сайте А работает а на сайте Б нет???
-
И снова, здравствуйте )
Посмотрел ваши выкладки и сдается мне, что проблема у вас при обработке тегов. Русские теги теряются либо при обработке, либо при передаче макросу content/pagesByAccountTags.
Обратите внимание на список вызываемых макросов (http://mironline.com.ua/market/svetilniki/svetil_niki_dekorativnye/potolochnye_svetilniki/potolochnye_svetilniki/svetil_nik_potolochnyj_massive_30050_56_10/?showStreamsCalls)
внизу вы увидите что вызывался макрос udata://stat/tagsCloud/notemplate/1000/816 и после него несколько раз макрос content/pagesByAccountTags , но все эти разы обрабатывались теги с английскими буквами. То есть, теги состоящие из кириллицы игнорировались (список всех тегов для данного случая легко увидеть вызвав http://mironline.com.ua/udata://stat/tagsCloud/notemplate/1000/)
Если посмотреть на второй сайт, то там мы видим (http://kids.mironline.com.ua/market/igrushki/radioupravlyaemye_modeli/mashinka_mercedes_benz_chernaya_1_14/?showStreamsCalls) что к концу списка вызовов также присутствует http://kids.mironline.com.ua/udata://stat/tagsCloud/notemplate/1000/ и он возвращает список тегов исключительно из кириллицы.
Поэтому, попробуйте изменить свой код, который обрабатывает каждый item из результатов макроса stat/tagsCloud и подставляет его в вызов макроса content/pagesByAccountTags
P.S. если проблема в преобразовании строки, то попробуйте решить вопрос не вызовом <xsl:call-template name="string-replace-all">, а php преобразованием текста через urlencode Передача значений на кириллице в кастомный метод (http://wiki.umisoft.ru/%D0%9F%D0%B5%D1%80%D0%B5%D0%B4%D0%B0%D1%87%D0%B0_%D0%B7%D0%BD%D0%B0%D1%87%D0%B5%D0%BD%D0%B8%D0%B9_%D0%BD%D0%B0_%D0%BA%D0%B8%D1%80%D0%B8%D0%BB%D0%BB%D0%B8%D1%86%D0%B5_%D0%B2_%D0%BA%D0%B0%D1%81%D1%82%D0%BE%D0%BC%D0%BD%D1%8B%D0%B9_%D0%BC%D0%B5%D1%82%D0%BE%D0%B4)
-
Спасибо Диниил!
Про stream я забыл, но для чего-то, когда-то его включал :)
Использование php:function очень помогло упростить весь документ!
Для использования php:function в документе xsl надо объявить его в шапке
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:php="http://php.net/xsl"
xsl:extension-element-prefixes="php"
>
Код обработки теперь такой
<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE xsl:stylesheet SYSTEM "ulang://i18n/constants.dtd:file">
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:php="http://php.net/xsl" xsl:extension-element-prefixes="php">
<xsl:include href="properties.xsl"/>
<xsl:include href="common-edit-form.xsl"/>
<xsl:include href="rss.xsl"/>
<xsl:include href="usel.xsl"/>
<xsl:template match="udata[@method='tagsCloud']" mode="objecttags">
<xsl:apply-templates select="//item" mode="objecttags"/>
</xsl:template>
<xsl:template match="item" mode="objecttags">
<xsl:apply-templates select="document(concat('udata://content/pagesByAccountTags/', php:function('urlencode',string(.))))" mode="objecttag"/>
</xsl:template>
<xsl:template match="udata[@method='pagesByAccountTags']" mode="objecttag">
<xsl:apply-templates select="//item" mode="objecttag"/>
</xsl:template>
<xsl:template match="item" mode="objecttag">
<div class="tag_item">
<a href="{@link}" id="tag_id_{@id}">
<xsl:value-of select="."/>
</a>
</div>
</xsl:template>
</xsl:stylesheet>